IF (VTK_USE_RENDERING AND VTK_USE_DISPLAY)
  SET(KIT Imaging)
  CREATE_TEST_SOURCELIST(Tests ${KIT}CxxTests.cxx
    ImportExport.cxx
    ImageBSplineCoefficients.cxx
    ImageWeightedSum.cxx
    ImageAutoRange.cxx
    ImageAccumulate.cxx
    ImageHistogram.cxx
    ImageHistogramStatistics.cxx
    ImageResize.cxx
    ImageResize3D.cxx
    ImageResizeCropping.cxx
    FastSplatter.cxx
    TestUpdateExtentReset.cxx
    EXTRA_INCLUDE vtkTestDriver.h
    )
  ADD_EXECUTABLE(${KIT}CxxTests ${Tests})
  TARGET_LINK_LIBRARIES(${KIT}CxxTests vtkRendering vtkIO)
  SET (TestsToRun ${Tests})
  LIST (REMOVE_ITEM TestsToRun ${KIT}CxxTests.cxx)

  #
  # Add all the executables
  FOREACH (test ${TestsToRun})
    GET_FILENAME_COMPONENT(TName ${test} NAME_WE)
    IF (VTK_DATA_ROOT)
      ADD_TEST(${TName} ${CXX_TEST_PATH}/${KIT}CxxTests ${TName}
        -D ${VTK_DATA_ROOT}
        -T ${VTK_BINARY_DIR}/Testing/Temporary
        -V Baseline/${KIT}/${TName}.png)
    ENDIF (VTK_DATA_ROOT)
  ENDFOREACH (test)
ENDIF (VTK_USE_RENDERING AND VTK_USE_DISPLAY)

